globals [randgene1 randgene2 randgene3 randgene4 randgene5 randgene6 randgene7 randgene8 totalMateDist totalMateDistSq totalGeneDist totalGeneDistSq numMatings 
colList numCols popList numSpecies avDist avGeneDist sdDist sdGeneDist dispNumNew numNew dispNumFailed numFailed]
turtles-own [gene species]


;;;;;;;;;;;;;;;;;;;;;;;
;;; Setup procedure ;;;
;;;;;;;;;;;;;;;;;;;;;;;

to setup 
  clear-all
  set-default-shape turtles "circle" 
  ;; set colList [red green orange sky brown magenta blue yellow violet lime pink turquoise cyan]
  set colList remove grey remove black base-colors
  set colList append append colList (map [? + 3] colList) (map [? - 3] colList)
  set numCols length colList
  set totalMateDist 0
  set numSpecies 0
  generate-new-agents N
  generate-random-genes
  if genePlottingOn [do-gene-plots]
  ifelse colouringOn 
    [colour_species] 
    [ask turtles [set color grey]]
end

;; generate initnal random agents
to generate-new-agents [num]
  create-turtles N [agent-init]
end

to agent-init
  ifelse initiallyRandPos
    [setxy random max-pxcor random max-pycor]
    [setxy (max-pxcor / 2) (max-pycor / 2)]
  set color grey
  show-turtle
  ifelse initiallyRandGenes
    [set gene n-values B [random 2]]
    [set gene n-values B [0]]
  set numNew numNew + 1
end

to generate-random-genes
  set randgene1 n-values B [random 2]
  set randgene2 n-values B [random 2]
  set randgene3 n-values B [random 2]
  set randgene4 n-values B [random 2]
  set randgene5 n-values B [random 2]
  set randgene6 n-values B [random 2]
  set randgene7 n-values B [random 2]
  set randgene8 n-values B [random 2]
end

;;;;;;;;;;;;;;;;;
;;; Main loop ;;;
;;;;;;;;;;;;;;;;;

to go
  if ticks >= maxTime [ stop ]
  set totalMateDist 0
  set numMatings 0
  set numNew 0
  set numFailed 0
  set totalGeneDist 0
  set totalMateDistSq 0
  set totalGeneDistSq 0
  ask turtles [act]
  do-distance-graphs
  ifelse colouringOn 
    [colour_species] 
    [ask turtles [set color grey]]
  if genePlottingOn [do-gene-plots]
  do-num-species-plot
  set dispNumFailed numFailed
  set dispNumNew numNew
  tick
end

to act
  let x xcor 
  let y ycor
  ifelse random-float 1 < Q
    [ask (one-of searchNear) [mateTo myself self x y]]
    [mateTo self self x y]
;;  die  
end

to-report searchNear
  let opSet []
  let dist S
  while [length opSet < 1] [
    set opSet findAllNearInSpace self dist
    set dist dist + 1
  ]
  report opSet
end

to mateTo [destInd ind xc yc]
  let mate ind
  let mates searchMates
  ifelse not empty? searchMates
    [ set mate one-of mates]
    [ ;; if there is no elidgible mate try the neighbours mating to this spot
      set numFailed numFailed + 1
      let othersNear shuffle findAllNearInSpace ind S
      let found false
      let othersMates []
      while [not empty? othersNear] [
        let otherNear first othersNear
        set othersNear but-first othersNear
        ask otherNear [set othersMates searchMates]
        if not empty? othersMates
          [set ind otherNear
           set mate one-of othersMates
           set found true]
      ]
      if not found [
        ask destInd [agent-init]
        stop
      ]
    ]
  let myGene [gene] of ind
  let myX [xcor] of ind
  let myY [ycor] of ind
  let otherGene [gene] of mate
  let otherX [xcor] of mate
  let otherY [ycor] of mate
  ask destInd [
    set gene cross myGene otherGene
    if random-float 1 < mu [set gene flip-bit random B gene]
    if random-float 1 < D [set xcor jogx xc set ycor jogy yc]
  ]
  
  ;; mating statistics 
  set numMatings numMatings + 1
  let dist distBetween myX myY otherX otherY
  set totalMateDist totalMateDist + dist
  set totalMateDistSq totalMateDistSq + dist ^ 2
  let hamm (hammingDist myGene otherGene)
  set totalGeneDist totalGeneDist + hamm
  set totalGeneDistSq totalGeneDistSq + hamm ^ 2
end

to-report findAllNearInSpace [ind dist]
  report remove ind (sort individualsToDist dist)
end

to-report searchMates
  let dist S
  let hamm G
  let opSet findAllNearInSpaceAndGenes self dist hamm
  while [length opSet < P] [
    set dist dist + 1
    set hamm hamm + 1
    set opSet findAllNearInSpaceAndGenes self dist hamm
  ]
  report opSet
end

to-report findAllNearInSpaceAndGenes [ind dist hamm]
  report filter [(hammingDist gene ([gene] of ?)) <= hamm] (remove ind (sort individualsToDist dist))
end

to-report searchMate
  report one-of searchMates
end


;;;;;;;;;;;;;;;;;;;;;;;
;; output
;;;;;;;;;;;;;;;;;;;;;;

to colour_species
  let t 0
  let curCol 0
  let mateList []
  let tCol black
  let othCol black
  ;;; 
  let tlist sort turtles
  ask turtles [set species 0]
  while [length tlist > 0] [
    set t first tlist
    set tlist but-first tlist
    set tCol [species] of t
    if tCol = 0 [
      set curCol curCol + 1
      set tCol curCol 
      ask t [set species tCol]
    ]
    set mateList filter [isMate t ? G] tlist
    foreach mateList [
      set othCol ([species] of ?)
      if othCol != tCol [
        ask ? [set species tCol]
        if (othCol != 0) [
          ask (turtles with [species = othCol]) [set species tCol]
        ]
      ]
    ]
  ]
  ;; now try and make the colouring as consistent as possible by always giving the same colour to the most frequent etc.
  set popList map [second ?1] (filter [first ?1 > 0] (sort-by [first ?1 > first ?2] (map [list (count turtles with [species = ?]) ?] n-values curCol [1 + ?])))
  set numSpecies length popList
  let tempColList colList
  let colRep grey
  foreach popList [
    ifelse not empty? tempColList 
      [set colRep first tempColList
      set tempColList but-first tempColList]
      [set colRep grey]
    ask turtles with [species = ?] [set color colRep]
  ]
end

to-report isMate [me ind m]
  report (hammingDist ([gene] of me) ([gene] of ind) <= m)
end

to do-distance-graphs
  set-current-plot "Mating Distances" 
  set avDist safeDiv totalMateDist numMatings
  set-current-plot-pen "av"
  plot avDist
  set sdDist sqrt ((safeDiv totalMateDistSq numMatings) - avDist ^ 2)
  set-current-plot-pen "av+sd"
  plot avDist + sdDist
  set-current-plot-pen "av-sd"
  plot max list 0 (avDist - sdDist)
  
  set-current-plot "Mating Gene Distances" 
  set-current-plot-pen "av"
  set avGeneDist safeDiv totalGeneDist numMatings
  plot avGeneDist
  set sdGeneDist sqrt ((safeDiv totalGeneDistSq numMatings) - avGeneDist ^ 2)
  set-current-plot-pen "av+sd"
  plot avGeneDist + sdGeneDist
  set-current-plot-pen "av-sd"
  plot max list 0 (avGeneDist - sdGeneDist)
end

to do-num-species-plot
  set-current-plot "Num Species" 
  ifelse colouringOn [set-plot-pen-color green] [set-plot-pen-color white]
  plot numSpecies
end

to do-gene-plots
  let sd 0.0015
  set-current-plot "genespace1" clear-plot
  set-current-plot "genespace2" clear-plot 
  set-current-plot "genespace3"  clear-plot
  set-current-plot "genespace4"  clear-plot
  foreach sort turtles [
    let tg [gene] of ?
    let cl ifelse-value colouringOn [[color] of ?] [grey]
    set-current-plot "genespace1" set-plot-pen-color cl
    plotxy ((hammingDist tg randgene1) / B) + random-normal 0 sd ((hammingDist tg randgene2) / B) + random-normal 0 sd 
    set-current-plot "genespace2" set-plot-pen-color cl
    plotxy ((hammingDist tg randgene3) / B) + random-normal 0 sd  ((hammingDist tg randgene4) / B) + random-normal 0 sd 
    set-current-plot "genespace3" set-plot-pen-color cl
    plotxy ((hammingDist tg randgene5) / B) + random-normal 0 sd  ((hammingDist tg randgene6) / B) + random-normal 0 sd 
    set-current-plot "genespace4" set-plot-pen-color cl
    plotxy ((hammingDist tg randgene7) / B) + random-normal 0 sd  ((hammingDist tg randgene8) / B) + random-normal 0 sd 
  ]
end

;;;;;;;;;;;;;;;;;;;;;;;
;; utils
;;;;;;;;;;;;;;;;;;;;;;

to-report safeSubList [lis srt en]
  let len length lis
  if en < 1 or srt > len [report []]
  report subList lis max list 0 srt min list en len
end

to-report flatten-once [lis]
  let op-list []
  foreach lis [
    foreach ? [set op-list fput ? op-list]
  ]
  report op-list
end

to-report insert [itm pos lis]
  report (sentence sublist lis 0 pos (list itm) sublist lis pos (length lis))
end

to-report insertAfter [itm pos lis]
  report insert itm (pos + 1) lis
end

to-report second [lis]
  report item 1 lis
end

to-report third [lis]
  report item 2 lis
end

to XXX
  let tt 1 
  set tt tt - 1
  set tt 1 / tt
end

to-report showPass [arg]
  show arg
  report arg
end

to-report posBiggest [lis]
  report position (reduce [ifelse-value (?1 >= ?2) [?1] [?2]] lis) lis 
end

to-report allPos [expr]
  let oplis [[0]]
  foreach but-first (n-values (length expr) [?]) [
    let pos ?
    let posLis allPos (item pos expr)
    set opLis append (map [fput pos ?1] posLis) opLis
  ]
  report opLis
end

to-report replaceAtPos [posList baseExpr insExpr]
  if posList = [0] [report insExpr]
  report replace-item (first posList) baseExpr (replaceAtPos (but-first posList) (item first posList baseExpr) insExpr)
end

to-report append [list1 list2]
  if empty? list1 [report list2]
  report fput (first list1) (append (but-first list1) list2)
end

to-report chooseProbilistically [numList]
  report findPos (random-float 1) cummulateList scaleList numList
end

to-report chooseReverseProbilistically [numList]
  if length numList = 1 [report 0]
  report findPos (random-float 1) cummulateList reverseProbList scaleList numList
end

to-report reverseProbList [numList]
  report map [1 - ?1] numList
end

to-report cummulateList [numList]
  report cummulateListR numList 0
end

to-report cummulateListR [numList cumm]
  if empty? numList [report []]
  let newCumm cumm + first numList
  report fput newCumm cummulateListR but-first numList newCumm
end

to-report scaleList [numList]
  let sumList sum numList
  if sumList = 0 [report numList]
  report map [?1 / sumList] numList
end

to-report findPos [vl numList]
  report findPosR vl numList 0
end

to-report findPosR [vl numList  pos]
  if empty? numList [report pos]
  if vl <= (first numList) [report pos]
  report findPosR vl but-first numList (1 + pos)
end

to-report freqOfIn [lis allList]
  report reduce [fput (numOfIn ?2 lis) ?1 ] (fput [] allList)
end  
  
to-report freqOf [lis]
  if empty? lis [report []]
  report fput (list (numOfIn first lis lis) (first lis)) (freqOf remove first lis lis)
end

to-report freqRep [lis]
  report sort-by [first ?1 > first ?2] filter [first ? > 1] freqOf lis 
end

to-report numOfIn [itm lis]
  report length (filter [itm = ?] lis)
end

to-report patchesToDist [dist]
  if dist = 0 [report patch-here]
  let patchList []
  foreach seq (-1 * dist) dist 1 [
    let xc ?
      foreach seq (-1 * dist) dist 1 [
        set patchList fput patch-at xc ? patchList
      ]
  ]
  report patch-set patchList
end

to-report individualsToDist [dist]
  report turtles-on patchesToDist dist
end

to-report hammingDist [gene1 gene2]
  report sum (map [ifelse-value (?1 = ?2) [0] [1]] gene1 gene2)
end

to null [x]
end

to-report distBetween [x1 y1 x2 y2]
  report (max list abs (x1 - x2) abs (y1 - y2))
;;  report sqrt (((x1 - x2) ^ 2) + ((y1 - y2) ^ 2))
end

to-report seq [from upto stp]
  report n-values (floor ((upto - from + 1) / stp)) [from + ? * stp]
end

to-report jogx [coord]
    set coord ((coord + jogStep) mod max-pxcor)
  report coord
end

to-report jogy [coord]
    set coord ((coord + jogStep) mod max-pycor)
  report coord
end

to-report jogStep
  report (random (2 * maxDispersalDistance + 1)) - maxDispersalDistance
end

to-report safeDiv [numer denom]
  if denom = 0 [report 0]
  report numer / denom
end  

to-report flip-bit [pos bitList]
  report replace-item pos bitList (1 - (item pos bitList))  
end

to-report cross [g1 g2]
  let ps random (1 + B)
  report append (safeSubList g1 0 ps) (safeSubList g2 ps B)
end
@#$#@#$#@
GRAPHICS-WINDOW
391
11
750
391
-1
-1
5.45313
1
10
1
1
1
0
1
1
1
0
63
0
63
1
1
1
ticks

CC-WINDOW
5
575
1077
670
Command Center
0

BUTTON
934
11
995
44
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
999
12
1062
45
go
go
T
1
T
OBSERVER
NIL
G
NIL
NIL

BUTTON
935
50
994
83
step
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

PLOT
6
398
344
560
Mating Distances
time
distance
0.0
1.0
0.0
20.0
true
false
PENS
"av" 1.0 0 -16777216 true
"av+sd" 1.0 0 -7500403 true
"av-sd" 1.0 0 -7500403 true

SLIDER
934
307
1065
340
maxTime
maxTime
0
10000
10000
100
1
NIL
HORIZONTAL

SLIDER
756
11
928
44
N
N
10
10000
500
10
1
NIL
HORIZONTAL

SLIDER
755
48
927
81
S
S
0
20
3
1
1
NIL
HORIZONTAL

SLIDER
756
85
928
118
G
G
0
100
10
1
1
NIL
HORIZONTAL

SLIDER
756
124
928
157
P
P
0
20
1
1
1
NIL
HORIZONTAL

SLIDER
756
162
928
195
Q
Q
0
1
0.3
0.01
1
NIL
HORIZONTAL

SLIDER
757
197
929
230
mu
mu
0
0.1
0.01
0.0001
1
NIL
HORIZONTAL

SLIDER
757
271
929
304
D
D
0
0.1
0.01
0.0001
1
NIL
HORIZONTAL

SLIDER
757
234
929
267
B
B
5
500
100
5
1
NIL
HORIZONTAL

SLIDER
934
271
1065
304
maxDispersalDistance
maxDispersalDistance
0
10
2
1
1
NIL
HORIZONTAL

BUTTON
999
49
1062
82
Recolour
colour_species
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

SWITCH
934
86
1064
119
colouringOn
colouringOn
1
1
-1000

PLOT
352
399
712
560
Mating Gene Distances
time
Hamming distance
0.0
1.0
0.0
5.0
true
false
PENS
"av" 1.0 0 -10899396 true
"av+sd" 1.0 0 -7500403 true
"av-sd" 1.0 0 -7500403 true

PLOT
5
11
195
201
genespace1
NIL
NIL
0.35
0.65
0.35
0.65
true
false
PENS
"default" 1.0 2 -16777216 true

PLOT
203
10
386
201
genespace2
NIL
NIL
0.35
0.65
0.35
0.65
true
false
PENS
"default" 1.0 2 -16777216 true

SWITCH
934
124
1066
157
genePLottingOn
genePLottingOn
1
1
-1000

PLOT
5
210
195
394
genespace3
NIL
NIL
0.35
0.65
0.35
0.65
true
false
PENS
"default" 1.0 2 -16777216 true

PLOT
204
208
387
390
genespace4
NIL
NIL
0.35
0.65
0.35
0.65
true
false
PENS
"default" 1.0 2 -16777216 false

PLOT
719
400
1066
561
Num Species
time
NIL
0.0
1.0
0.0
8.0
true
false
PENS
"default" 1.0 0 -10899396 true

SWITCH
934
162
1067
195
initiallyRandGenes
initiallyRandGenes
1
1
-1000

MONITOR
758
309
900
350
Num Species (if colouring on)
numSpecies
2
1
10

MONITOR
832
353
926
394
Av Gene Mate Dist
avGeneDist
1
1
10

MONITOR
758
353
828
394
Av Mate Dist
avDist
1
1
10

SWITCH
935
197
1068
230
initiallyRandPos
initiallyRandPos
0
1
-1000

MONITOR
943
352
1001
393
num new
dispNumNew
17
1
10

MONITOR
1007
352
1064
393
num fail
dispNumFailed
17
1
10

@#$#@#$#@
WHAT IS IT?
-----------
This model is an attempted reimplementation of the model described in:

de Aguiar MA, Baranger M, Baptestini EM, Kaufman L, Bar-Yam Y. (2009) Global Patterns of speciation and diverity.  Nature. Jul 16;460(7253):334-5

at: http://www.nature.com/nature/journal/v460/n7253/full/nature08168.html


HOW TO USE IT
-------------
Press setup to initialise the model, then "step" for a single step, or "go" for continuous running.  

You can turn on species colouring, but this slows the simulation up.  I am not 100% sure about my colouring algorithm.

The "Recolour" button colurs the individuals as to species when the simulation has been paused.


AREAS OF UNCERTAINTY IN THE SIMULATION SPECIFICATION
----------------------------------------------------

It was not clear what happens in the "Q" case if there was not another in the spatial vicinity of an individual - I have caused a widening search until there is.

It was not clear if the update of individuals (their mating etc.) was in parallel or in a random sequence or what - I have used a random sequence here.

THE GRAPHS AND VISUALISATIONS
------------------

The main display shows the position of (topmost) individuals at each location.  The colouring (when used) shows the different species, unless white dots remain, in which case there are not enough colours to complete this.  Thus if there are white dots some of the individuals that are coloured differently might, in fact, be members of the same species.  (species as defined in the paper).

"genespace1" etc. are projections of the positions of the genes of all individuals against (fixed) random genes.

The two graphs show the average spatial and genetic distances of all matings.  Grey lines show average plus or minus a standard deviation (if greater than zero).

OBSERVATTIONS
-------------

The simulation is very slow to start with, due to the need for inviduals to widen their search for suitable mates.  This reduces quickly after a few generations.  I would guess that if a random genetically suitable mate was chosen if there was not one within spatial range would have a similar effect, if slightly less plausible.

The simulation runs much faster if the continual colouring and genespace projections are turned off.

The purpose of P is not at all clear.  If the mating distance limitation is there to be realistic then surely it should be fixed.  The bit about widening the search until one finds a mate is surely just a fix due to the wish to keep the model simple and with a fixed population.

I also dont understand in the Q case why the individual ends up at the original individual's location rather than being dispersed from its location.  This still satisfies the idea of a local fixed carrying capacity.  There seems to be a slight conceptual confusion between taking the individual's place in the ecosystem (but places are not kept as many are left blank and multiple organisms can inhabit each location) and a localised carrying capacity (but its not local its global to the whole environment, although locally, in the short term numbers are roughly conserved - however in this case why distribute from the original individual).

The mate search widening seems a fudge.  If the spatial and genetic differences are a preference then it should be implemented as such, if it is a limitation then there can be no search widening.  It seems that the average mating distance hovers just *above* the spatial limit for some reason (if one adjusts S upwards the average then adjust to be just above the new limit).  Maybe some other way of starting the process off could be introduced instead of the widening.

EXTENSIONS
----------

I have allowed alternate initialisations - random or uniform initial genes, and random or uniform initial position, so the other cases can be compared.

The P=0 case is now included, in this case the search for mates is not widened beyond the original S and G restrictions (since >0 mates satisfies the search).  Despite the contradictions, in order to keep as far as possible within the spirit of the original model, the following happnes: in the case where P=0 and there is no possible mate then if there is a local other that can mate it does with the individual ending up at the original position, if there is none at all a random new individual is placed into the environment.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.0.4
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@